mirror of
https://github.com/torvalds/linux.git
synced 2025-12-07 20:06:24 +00:00
26e7aacb83
Add 2 early command line parameters that allow to downgrade satp mode (using the same naming as x86): - "no5lvl": use a 4-level page table (down from sv57 to sv48) - "no4lvl": use a 3-level page table (down from sv57/sv48 to sv39) Note that going through the device tree to get the kernel command line works with ACPI too since the efi stub creates a device tree anyway with the command line. In KASAN kernels, we can't use the libfdt that early in the boot process since we are not ready to execute instrumented functions. So instead of using the "generic" libfdt, we compile our own versions of those functions that are not instrumented and that are prefixed so that they do not conflict with the generic ones. We also need the non-instrumented versions of the string functions and the prefixed versions of memcpy/memmove. This is largely inspired by commitaacd149b62("arm64: head: avoid relocating the kernel twice for KASLR") from which I removed compilation flags that were not relevant to RISC-V at the moment (LTO, SCS). Also note that we have to link with -z norelro to avoid ld.lld to throw a warning with the new .got sections, like in commit311bea3cb9("arm64: link with -z norelro for LLD or aarch64-elf"). Signed-off-by: Alexandre Ghiti <alexghiti@rivosinc.com> Tested-by: Björn Töpel <bjorn@rivosinc.com> Reviewed-by: Björn Töpel <bjorn@rivosinc.com> Link: https://lore.kernel.org/r/20230424092313.178699-2-alexghiti@rivosinc.com Signed-off-by: Palmer Dabbelt <palmer@rivosinc.com>
177 lines
3.2 KiB
ArmAsm
177 lines
3.2 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
/*
|
|
* Copyright (C) 2012 Regents of the University of California
|
|
* Copyright (C) 2017 SiFive
|
|
*/
|
|
|
|
#define RO_EXCEPTION_TABLE_ALIGN 4
|
|
#define RUNTIME_DISCARD_EXIT
|
|
|
|
#ifdef CONFIG_XIP_KERNEL
|
|
#include "vmlinux-xip.lds.S"
|
|
#else
|
|
|
|
#include <asm/pgtable.h>
|
|
#define LOAD_OFFSET KERNEL_LINK_ADDR
|
|
|
|
#include <asm/vmlinux.lds.h>
|
|
#include <asm/page.h>
|
|
#include <asm/cache.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/set_memory.h>
|
|
#include "image-vars.h"
|
|
|
|
#include <linux/sizes.h>
|
|
OUTPUT_ARCH(riscv)
|
|
ENTRY(_start)
|
|
|
|
jiffies = jiffies_64;
|
|
|
|
SECTIONS
|
|
{
|
|
/* Beginning of code and text segment */
|
|
. = LOAD_OFFSET;
|
|
_start = .;
|
|
HEAD_TEXT_SECTION
|
|
. = ALIGN(PAGE_SIZE);
|
|
|
|
.text : {
|
|
_text = .;
|
|
_stext = .;
|
|
TEXT_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
KPROBES_TEXT
|
|
ENTRY_TEXT
|
|
IRQENTRY_TEXT
|
|
SOFTIRQENTRY_TEXT
|
|
_etext = .;
|
|
}
|
|
|
|
. = ALIGN(SECTION_ALIGN);
|
|
__init_begin = .;
|
|
__init_text_begin = .;
|
|
.init.text : AT(ADDR(.init.text) - LOAD_OFFSET) ALIGN(SECTION_ALIGN) { \
|
|
_sinittext = .; \
|
|
INIT_TEXT \
|
|
_einittext = .; \
|
|
}
|
|
|
|
. = ALIGN(8);
|
|
__soc_early_init_table : {
|
|
__soc_early_init_table_start = .;
|
|
KEEP(*(__soc_early_init_table))
|
|
__soc_early_init_table_end = .;
|
|
}
|
|
__soc_builtin_dtb_table : {
|
|
__soc_builtin_dtb_table_start = .;
|
|
KEEP(*(__soc_builtin_dtb_table))
|
|
__soc_builtin_dtb_table_end = .;
|
|
}
|
|
/* we have to discard exit text and such at runtime, not link time */
|
|
.exit.text :
|
|
{
|
|
EXIT_TEXT
|
|
}
|
|
|
|
__init_text_end = .;
|
|
. = ALIGN(SECTION_ALIGN);
|
|
#ifdef CONFIG_EFI
|
|
. = ALIGN(PECOFF_SECTION_ALIGNMENT);
|
|
__pecoff_text_end = .;
|
|
#endif
|
|
/* Start of init data section */
|
|
__init_data_begin = .;
|
|
INIT_DATA_SECTION(16)
|
|
|
|
/* Those sections result from the compilation of kernel/pi/string.c */
|
|
.init.pidata : {
|
|
*(.init.srodata.cst8*)
|
|
*(.init__bug_table*)
|
|
*(.init.sdata*)
|
|
}
|
|
|
|
.init.bss : {
|
|
*(.init.bss) /* from the EFI stub */
|
|
}
|
|
.exit.data :
|
|
{
|
|
EXIT_DATA
|
|
}
|
|
PERCPU_SECTION(L1_CACHE_BYTES)
|
|
|
|
.rel.dyn : {
|
|
*(.rel.dyn*)
|
|
}
|
|
|
|
__init_data_end = .;
|
|
|
|
. = ALIGN(8);
|
|
.alternative : {
|
|
__alt_start = .;
|
|
*(.alternative)
|
|
__alt_end = .;
|
|
}
|
|
__init_end = .;
|
|
|
|
/* Start of data section */
|
|
_sdata = .;
|
|
RO_DATA(SECTION_ALIGN)
|
|
.srodata : {
|
|
*(.srodata*)
|
|
}
|
|
|
|
. = ALIGN(SECTION_ALIGN);
|
|
_data = .;
|
|
|
|
RW_DATA(L1_CACHE_BYTES, PAGE_SIZE, THREAD_ALIGN)
|
|
.sdata : {
|
|
__global_pointer$ = . + 0x800;
|
|
*(.sdata*)
|
|
}
|
|
|
|
.rela.dyn : ALIGN(8) {
|
|
__rela_dyn_start = .;
|
|
*(.rela .rela*)
|
|
__rela_dyn_end = .;
|
|
}
|
|
|
|
.got : { *(.got*) }
|
|
|
|
#ifdef CONFIG_RELOCATABLE
|
|
.data.rel : { *(.data.rel*) }
|
|
.plt : { *(.plt) }
|
|
.dynamic : { *(.dynamic) }
|
|
.dynsym : { *(.dynsym) }
|
|
.dynstr : { *(.dynstr) }
|
|
.hash : { *(.hash) }
|
|
.gnu.hash : { *(.gnu.hash) }
|
|
#endif
|
|
|
|
#ifdef CONFIG_EFI
|
|
.pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
|
|
__pecoff_data_raw_size = ABSOLUTE(. - __pecoff_text_end);
|
|
__pecoff_data_raw_end = ABSOLUTE(.);
|
|
#endif
|
|
|
|
/* End of data section */
|
|
_edata = .;
|
|
|
|
BSS_SECTION(PAGE_SIZE, PAGE_SIZE, 0)
|
|
|
|
#ifdef CONFIG_EFI
|
|
. = ALIGN(PECOFF_SECTION_ALIGNMENT);
|
|
__pecoff_data_virt_size = ABSOLUTE(. - __pecoff_text_end);
|
|
__pecoff_data_virt_end = ABSOLUTE(.);
|
|
#endif
|
|
_end = .;
|
|
|
|
STABS_DEBUG
|
|
DWARF_DEBUG
|
|
ELF_DETAILS
|
|
.riscv.attributes 0 : { *(.riscv.attributes) }
|
|
|
|
DISCARDS
|
|
}
|
|
#endif /* CONFIG_XIP_KERNEL */
|